xyz.F90

Go to the documentation of this file.

! This file is part of the 'atomes' software.
!
! 'atomes' is free software: you can redistribute it and/or modify it under the terms
! of the GNU Affero General Public License as published by the Free Software Foundation,
! either version 3 of the License, or (at your option) any later version.
!
! 'atomes' is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
! without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
! See the GNU General Public License for more details.
!
! You should have received a copy of the GNU Affero General Public License along with 'atomes'.
! If not, see <https://www.gnu.org/licenses/>
!
! Copyright (C) 2022-2024 by CNRS and University of Strasbourg
!
 
INTEGER (KIND=c_int) FUNCTION read_xyz (xyz_f, lxyz, is_npt) bind (C,NAME='read_xyz_')
 
!INTEGER FUNCTION read_xyz (xyz_file, lxyz)
 
!
! Lecture of atom types and coordinates - XYZ files
!
USE parameters
 
IMPLICIT NONE
 
LOGICAL :: isok
INTEGER (KIND=c_int), INTENT(IN) :: lxyz, is_npt
CHARACTER (KIND=c_char), DIMENSION(*), INTENT(IN) :: xyz_f
CHARACTER (LEN=lxyz) :: xyz_file
INTERFACE
INTEGER FUNCTION test_length(UNITFILE, NATL)
  INTEGER, INTENT(IN) :: unitfile, natl
END FUNCTION
END INTERFACE
 
do i=1, lxyz
  xyz_file(i:i) = xyz_f(i)
enddo
 
read_xyz=1
 
inquire (file=xyz_file, exist=isok)
if (isok) then
 
  open (unit=20, file=xyz_file, action='read', status='old', err=001)
  ns=0
  read (20, *, err=002) na
  ns = test_length(20, na+2)
  if (ns .gt. 0) then
 
    rewind(20)
    if (allocated(fullpos)) deallocate(fullpos)
    allocate (fullpos(na,3,ns), stat=err)
    if (err .ne. 0) then
      call show_error ("Impossible to allocate memory"//char(0), &
                       "Function: read_xyz"//char(0), "Table: FULLPOS"//char(0))
    endif
    if (allocated(tab_of_type)) deallocate(tab_of_type)
    allocate (tab_of_type(na), stat=err)
    if (err .ne. 0) then
      call show_error ("Impossible to allocate memory"//char(0), &
                       "Function: read_xyz"//char(0), "Table: TAB_OF_TYPE"//char(0))
    endif
 
    do i=1, ns
      read (20, *, err=002)
      read (20, *, err=002)
      do j=1, na
        read (20, *, err=002) tab_of_type(j), fullpos(j,1,i), fullpos(j,2,i), fullpos(j,3,i)
      enddo
    enddo
    if (is_npt .eq. 1) call send_steps (ns)
    read_xyz=0
  else
    read_xyz=2
  endif
 
  002 continue
 
  close (20)
 
  001 continue
 
endif
 
END FUNCTION
 
INTEGER FUNCTION test_length (UNITFILE, NATL)
 
IMPLICIT NONE
INTEGER, INTENT(IN) :: unitfile, natl
INTEGER :: lenf
INTEGER :: eof
 
rewind(unitfile)
eof=0
lenf=0
do while (eof .eq. 0)
  read (unitfile, *, iostat=eof)
  lenf=lenf+1
enddo
lenf=lenf-1
 
test_length=mod(lenf,natl)
if (test_length .eq. 0) then
 test_length=lenf/natl
else
 test_length=0
endif
 
END FUNCTION
 
SUBROUTINE send_label (sp_id, sp_ln, spec_label) bind (C,NAME='send_label_')
 
USE parameters
 
IMPLICIT NONE
 
INTEGER (KIND=c_int), INTENT(IN) :: sp_id, sp_ln
CHARACTER (KIND=c_char), DIMENSION(sp_ln), INTENT(IN) :: spec_label
 
tl(sp_id)="  "
do i=1, sp_ln
  tl(sp_id)(i:i) = spec_label(i)
enddo
 
END SUBROUTINE
 
INTEGER (KIND=c_int) FUNCTION write_xyz (xyz_f, lxyz, fxyz, txyz) bind (C,NAME='write_xyz_')
 
!
! output of atom types and coordinates - Multiple XYZ files
!
 
USE parameters
 
IMPLICIT NONE
 
INTEGER (KIND=c_int), INTENT(IN) :: lxyz, fxyz, txyz
CHARACTER (KIND=c_char), DIMENSION(*), INTENT(IN) :: xyz_f
DOUBLE PRECISION, DIMENSION(3) :: savep
CHARACTER (LEN=lxyz) :: xyz_file
 
INTERFACE
INTEGER FUNCTION test_length(UNITFILE, NATL)
  INTEGER, INTENT(IN) :: unitfile, natl
END FUNCTION
END INTERFACE
 
do i=1, lxyz
  xyz_file(i:i) = xyz_f(i)
enddo
 
write_xyz=1
open (unit=20, file=xyz_file, action='write', status='unknown', err=001)
do i=1, ns
  write (20, '(i10)') na
  write (20, *)
  do j=1, na
    if (fxyz .eq. 1) then
      if (ncells .gt. 1) then
        nbox => the_box(i)
      else
        nbox => the_box(1)
      endif
      savep = matmul(fullpos(j,:,i),nbox%carttofrac)
    else
      savep = fullpos(j,:,i)
      if (txyz .eq. 1) then
        savep(:) = savep(:)/angtobohr
      endif
    endif
    write (20, '(a2,3(3x,f15.10))', err=002) tl(lot(j)), savep
  enddo
enddo
write_xyz=0
 
002 continue
 
close (20)
 
001 continue
 
END FUNCTION